S-probe, Where do I get this file???

[Petestorbach]

I've got my shopbot set up to do probing with the paper clip and tin foil method (using concuctivity)

Where can I find the probing file?

All the other files that come packaged with the software mention this file but it's not in my directory.

Any advice?

Thanks Pete

[edwardmc]

It is in the sbparts folder . if you are using the newest version of shopbot the windows ver. I dont think thay have it working yet. But I could be wrong.

[bjwat@comcast.net]

Pete,
Look over on the SB site under Bill's Corner. He has the latest and greatest files for download in that section. I know that there have been updates to the probe files.

-Brady

[Petestorbach]

Hi Guys, I just downloaded the newest software and the file is NOT there. There is no S-probe.sbp anywhere with the software I downloaded. Where do I get this file? Can somebody post it if they have it?

Thanks, Pete

[paul_nielsen]

Hey Pete,

Send me your email address, and I'll send you the files.

Paul

[kerrazy]

If you are running the windows version of the SB software, It will not work so do not use the SB_Probe files unless it is the DOS version.
Dale

[frank]

Hi Pete,

In order to get a probe file to work using foil (normally open switch), you will have to edit the ON INPUT statements in the probe file that is set up for a normally closed switch. Change each 1,1 to 1,0 and each 1,0 to 1,1. If you need help doing this, give me a call.

[Petestorbach]

still can't get this to work. Tried changing 1,0 to 1,0 but I can't get it to work. I get a message saying either probe Probe Not Working ----> EXITING ! or No Clearance or Problem with Probe.

Here is the file before I edited it. Perhaps someone can show me what I need to do?

Thanks Pete

'S_Prb3d2.sbp 12/99,7/00,6/01 (GB, TH)
' This is a sample of a probing/digitizing routine for use with ShopBot's 3D-sensing probe
' **This program only works with a NORMALLY-CLOSED SWITCH such as in this probe
' For a general purpose, normally-open, probing program see: S_probe.sbp
' The program is designed to either run with a set of default values that you can edit
' in the code below, or to get User Input of probing set-up values when it is run.
' This program probes a row of points in the X direction and then steps over a row in the Y
' Copyright 1998-2001. ShopBot Tools, Inc.

'User takes responsibility for the effects and outcomes of the use of this program.
'Test Run this program in Preview Mode and with air cutting above material to make
' sure you are satisfied that it is doing what you expect it to do.
'

'Initialize
SA, 'absolute increment mode
SC,0 'turn smoothing (move blocks) OFF
SL, 'clear all variables in memory
&zmax=-2 'maximum probe depth
&tol=.005 'controls IF test comparisons, avoids small rounding/position errors
&surfacetol=.002 'used to keep clear of surface if a lot of it is flat

'Default variables, these are values that will be used if you want to skip the prompts
'... you could change these to suite your own needs
&outname="c:\sbparts\scanned.sbp" 'file name with or without .sbp, add path
&xstart = 0 'X starting position
&xmove = 0.05 'X step increment
&xdist = 1 'X distance of probe pattern
&ystart = 0 'Y starting position
&ymove = 0.05 'Y step increment
&ydist = 1 'Y distance of probe pattern
&safeclear = 0.5
&defaults = "N"

'Now you let the software know whether you want to input values or not
INPUT "Use Default settings (Y\N): " &defaults
&defaults = "&defaults"

IF &defaults="Y" THEN GOTO START 'otherwise you'll be prompted by the following lines for them

'Get user-entered probing values
INPUT "Name for 3D cutting file ( <Path\>filename.sbp ): " &outname
INPUT "X Starting Position ->" &xstart
INPUT "Y Starting Poistion ->" &ystart
INPUT "X pattern size ->" &xdist
INPUT "Y pattern size ->" &ydist
INPUT "X step distance ->" &xmove
INPUT "Y step distance ->" &ymove
INPUT "Safe clearance height (pull up here for big moves) ->" &safeclear

START:
&xmax=&xstart+&xdist-&tol
&ymax=&ystart+&ydist-&tol
&zstart=&safeclear
&xmin=&xstart+&tol
&ymin=&ystart+&tol
&xloc=&xstart
&yloc=&ystart
&xdir = 1
&ydir = 1

'You will be creating a Part File on the fly ... as you scan
OPEN &outname FOR OUTPUT AS #1
WRITE #1, "SA" 'put first command in new file

' Ready to start -----> (anykey to continue)
PAUSE

'Moving to start location
JZ, &safeclear
J2, &xstart, &ystart
MS, 1, 0.6 'sample speeds, you may want to set ramps to

'Check to make sure probe attached by checking the system variable status for input 1
IF %(51)=1 THEN GOTO CONTINUE1
PRINT " Probe Not Working ----> EXITING !"
PAUSE 6
END

CONTINUE1:
PRINT " Probe Working ----> Start? (anykey to continue)"
PAUSE

DOWN_CYCLE:
ON INPUT(1,0) GOTO CONTACT 'Set up response to contact
&xloc = &xloc + (&xmove*&xdir) 'Compute for next lateral move
MZ, &zmax 'DOWN HERE ... looking for basic bottom
' -->expected -off- hit bottom
OVER_CYCLE:
ON INPUT(1,1)
ON INPUT(1,0) GOTO CONTACT
MX, &xloc 'MOVING OVER HERE ... looking for edge
' -->expected -off- hit side
IF &xloc<&xmin THEN GOTO NEXTY
IF &xloc>&xmax THEN GOTO NEXTY
GOTO DOWN_CYCLE

CONTACT:
ON INPUT(1,0)
WRITE #1, "M3", %(1), %(2), %(3) 'Write 3d location on Contact
MZ, %(3)+&surfacetol 'Pulls up a bit to control unnecessary bouncing on a flat surface
ON INPUT(1,1) GOTO OVER_CYCLE 'When clear goto next lateral
MZ, &safeclear 'UP until we are clear
'No Clearance or Problem with Probe!
PAUSE

END 'If we don't get clear we'd better stop !

NEXTY:
ON INPUT(1,0) 'Temp off
WRITE #1, "M3", %(1), %(2), %(3) 'Write last location this row
JZ, &safeclear 'Up a tad
&yloc=&yloc + (&ymove*&ydir)
IF &yloc>&ymax THEN GOTO LAST
JY, &yloc 'Here we step over in the Y direction
&xdir=&xdir*-1
GOTO DOWN_CYCLE

LAST:
JZ, &safeclear
WRITE #1, "JZ", &safeclear
J2, &xstart, &ystart
WRITE #1, "J2", &xstart, &ystart
CLOSE #1
'Finished Probing ...
PAUSE 5

END

[bjwat@comcast.net]

Pete,
You can't use PRB3D2.sbp with a paperclip!!! This file is meant to be used with the ShopBot 3D probe. A paperclip will not work.

I have the SB probe so I've never had the need to use the foil/rod method. The foil/rod method will NOT work on 3D. It is only for edge finding routines.

I STRONGLY advise reading the release notes for each probe file when prompted when you attempt to run it. Some are made for the SB probe, some 3D, and others for rod and foil method. Each specificly tells you if it is meant to run with the SB Probe or Rod.

-Brady

PS- Add your e-mail address to your profile so that one of us can send you the correct file if we find it...

[frank]

I didn't mention that if you change one of the the probe files that is written for a normally closed switch, then you have to delete the section in the file that is checking to see if the probe is hooked up. Search for the word "checking" to locate that part of the file and delete that routine.

[bill.young]

Hey Pete,

Look for the line that says...

IF %(51)=1 THEN GOTO CONTINUE1

...and change it to...

IF %(51)=0 THEN GOTO CONTINUE1

What that line does is test to make sure that the probe is connected correctly and not touching the surface at the start of the routine. It does this by checking to see if the input switch is ON which is the normal condition of the ShopBot probe when it's not making contact. Since you're using a probing system that is normally OFF, you need to change that test so that it checks for OFF (0) instead of ON (1).

That should solve your problem.

Bill

[Petestorbach]

Sucess!

That did it!

OK, now can somebody tell me what file I can do the same modifications on that will generate a 3D DXF and not a SBP file. I want to be able to clean it up in Rhino.

[Brown]

Pete,

Some of us have software that allows us to "backplot" to a DXF file.

Ron

[coastal]

The probing routine will create a series of m3 commands. You will need to delete the M3 from the file and any spaces between the commas. In A word processor do a find and replace the M3 Commands with a none breaking space. After all spaces , Move and jog commands have been deleted you will have a list of coordinates. Then at the beginning of the list type polyline. Then highlight the list and copy (File,Edit,select all; File Edit Copy). Open Rhino at the command prompt press the ctrl and v at the same time. If the list of coordinates was formatted correct (with no spaces and no shopbot commands) Rhino will start plotting the coordinates.

[bjwat@comcast.net]

Wow Ryan!
That's a great little piece of info! Thanks for sharing it!

-Brady